Handbook_of_statistical_analysis_using_SAS

Display 5.9

Although the results are similar to those for the untransformed observations, the three-way interaction is now only marginally significant. If no substantive explanation of this interaction is forthcoming, it might be preferable to interpret the results in terms of the very significant main effects and fit a main-effects-only model to the log-transformed blood pressures. In addition, we can use Scheffe’s multiple comparison test (Fisher and Van Belle, 1993) to assess which of the three drug means actually differ.

proc anova data=hyper; class diet drug biofeed;

model logbp=diet drug biofeed; means drug / scheffe;

run;

The results are shown in Display 5.10. Each of the main effects is seen to be highly significant, and the grouping of means resulting from the application of Scheffe’s test indicates that drug X produces lower blood pressures than the other two drugs, whose means do not differ.

©2002 CRC Press LLC

The ANOVA Procedure

Class Level Information

Number of observations 72

The ANOVA Procedure

Dependent Variable: logbp

The ANOVA Procedure

Scheffe's Test for logbp

NOTE: This test controls the Type I experimentwise error rate.

©2002 CRC Press LLC

Means with the same letter are not significantly different.

Display 5.10

Exercises

5.1Compare the results given by Bonferonni t-tests and Duncan’s multiple range test for the three drug means, with those given by Scheffe’s test as reported in Display 5.10.

5.2Produce box plots of the log-transformed blood pressures for (a) diet present, diet absent; (b) biofeedback present, biofeedback absent; and (c) drugs X, Y, and Z.

©2002 CRC Press LLC

Chapter 6

Analysis of Variance II:

School Attendance

Amongst Australian

Children

6.1 Description of Data

The data used in this chapter arise from a sociological study of Australian Aboriginal and white children reported by Quine (1975); they are given in Display 6.1. In this study, children of both sexes from four age groups (final grade in primary schools and first, second, and third form in secondary school) and from two cultural groups were used. The children in each age group were classified as slow or average learners. The response variable of interest was the number of days absent from school during the school year. (Children who had suffered a serious illness during the year were excluded.)

©2002 CRC Press LLC

Note: A, Aboriginal; N, non-Aboriginal; F, female; M, male; F0, primary; F1, first form; F2, second form; F3, third form; SL, slow learner; AL, average learner.

Display 6.1

©2002 CRC Press LLC

6.2 Analysis of Variance Model

The basic design of the study is a 4 × 2 × 2 × 2 factorial. The usual model

for yijklm, the number of days absent for the ith child in the jth sex group, the kth age group, the lth cultural group, and the mth learning group, is

where the terms represent main effects, first-order interactions of pairs of factors, second-order interactions of sets of three factors, and a third-order interaction for all four factors. (The parameters must be constrained in some way to make the model identifiable. Most common is to require

they sum to zero over any subscript.) The ijklm represent random error terms assumed to be normally distributed with mean zero and variance σ 2.

The unbalanced nature of the data in Display 6.1 (there are different numbers of observations for the different combinations of factors) presents considerably more problems than encountered in the analysis of the balanced factorial data in the previous chapter. The main difficulty is that when the data are unbalanced, there is no unique way of finding a “sums of squares” corresponding to each main effect and each interaction because these effects are no longer independent of one another. It is now no longer possible to partition the total variation in the response variable into non-overlapping or orthogonal sums of squares representing factor main effects and factor interactions. For example, there is a proportion of the variance of the response variable that can be attributed to (explained by) either sex or age group, and, consequently, sex and age group together explain less of the variation of the response than the sum of which each explains alone. The result of this is that the sums of squares that can be attributed to a factor depends on which factors have already been allocated a sums of squares; that is, the sums of squares of factors and their interactions depend on the order in which they are considered.

The dependence between the factor variables in an unbalanced factorial design and the consequent lack of uniqueness in partitioning the variation in the response variable has led to a great deal of confusion regarding what is the most appropriate way to analyse such designs. The issues are not straightforward and even statisticians (yes, even statisticians!) do not wholly agree on the most suitable method of analysis for all situations, as is witnessed by the discussion following the papers of Nelder (1977) and Aitkin (1978).

©2002 CRC Press LLC

Essentially the discussion over the analysis of unbalanced factorial designs has involved the question of what type of sums of squares should be used. Basically there are three possibilities; but only two are considered here, and these are illustrated for a design with two factors.

6.2.1 Type I Sums of Squares

These sums of squares represent the effect of adding a term to an existing model in one particular order. Thus, for example, a set of Type I sums of squares such as:

ASSA

BSSB A AB SSAB A,B

essentially represent a comparison of the following models:

The use of these sums of squares in a series of tables in which the effects are considered in different orders (see later) will often provide the most satisfactory way of answering the question as to which model is most appropriate for the observations.

6.2.2 Type III Sums of Squares

Type III sums of squares represent the contribution of each term to a model including all other possible terms. Thus, for a two-factor design, the sums of squares represent the following:

ASSA B,AB

BSSB A,AB

AB SSAB A,B

©2002 CRC Press LLC

(SAS also has a Type IV sum of squares, which is the same as Type III unless the design contains empty cells.)

In a balanced design, Type I and Type III sums of squares are equal; but for an unbalanced design, they are not and there have been numerous discussions regarding which type is most appropriate for the analysis of such designs. Authors such as Maxwell and Delaney (1990) and Howell (1992) strongly recommend the use of Type III sums of squares and these are the default in SAS. Nelder (1977) and Aitkin (1978), however, are strongly critical of “correcting” main effects sums of squares for an interaction term involving the corresponding main effect; their criticisms are based on both theoretical and pragmatic grounds. The arguments are relatively subtle but in essence go something like this:

When fitting models to data, the principle of parsimony is of critical importance. In choosing among possible models, we do not adopt complex models for which there is no empirical evidence.

Thus, if there is no convincing evidence of an AB interaction, we do not retain the term in the model. Thus, additivity of A and B is assumed unless there is convincing evidence to the contrary.

So the argument proceeds that Type III sum of squares for A in which it is adjusted for AB makes no sense.

First, if the interaction term is necessary in the model, then the experimenter will usually want to consider simple effects of A at each level of B separately. A test of the hypothesis of no A main effect would not usually be carried out if the AB interaction is significant.

If the AB interaction is not significant, then adjusting for it is of no interest, and causes a substantial loss of power in testing the A and B main effects.

(The issue does not arise so clearly in the balanced case, for there the sum of squares for A say is independent of whether or not interaction is assumed. Thus, in deciding on possible models for the data, the interaction term is not included unless it has been shown to be necessary, in which case tests on main effects involved in the interaction are not carried out; or if carried out, not interpreted — see biofeedback example in Chapter 5.)

The arguments of Nelder and Aitkin against the use of Type III sums of squares are powerful and persuasive. Their recommendation to use Type I sums of squares, considering effects in a number of orders, as the most suitable way in which to identify a suitable model for a data set is also convincing and strongly endorsed by the authors of this book.

©2002 CRC Press LLC

6.3 Analysis Using SAS

It is assumed that the data are in an ASCII file called ozkids.dat in the current directory and that the values of the factors comprising the design are separated by tabs, whereas those recoding days of absence for the subjects within each cell are separated by commas, as in Display 6.1. The data can then be read in as follows:

data ozkids;

infile 'ozkids.dat' dlm=' ,' expandtabs missover; input cell origin $ sex $ grade $ type $ days @;

do until (days=.); output;

input days @; end;

input;

run;

The expandtabs option on the infilestatement converts tabs to spaces so that list input can be used to read the tab-separated values. To read the comma-separated values in the same way, the delimiter option (abbreviated dlm) specifies that both spaces and commas are delimiters. This is done by including a space and a comma in quotes after dlm=. The missover option prevents SAS from reading the next line of data in the event that an input statement requests more data values than are contained in the current line. Missing values are assigned to the variable(s) for which there are no corresponding data values. To illustrate this with an example, suppose we have an input statement input x1-x7;. If a line of data only contains five numbers, by default SAS will go to the next line of data to read data values for x6 and x7. This is not usually what is intended; so when it happens, there is a warning message in the log: “SAS went to a new line when INPUT statement reached past the end of a line.” With the missover option, SAS would not go to a new line but x6 and x7 would have missing values. Here we utilise this to determine when all the values for days of absence from school have been read.

The input statement reads the cell number, the factors in the design, and the days absent for the first observation in the cell. The trailing @ at the end of the statement holds the data line so that more data can be read from it by subsequent input statements. The statements between the do until and the following end are repeatedly executed until the days variable has a missing value. The output statement creates an observation in the output data set. Then another value of days is read, again holding the data line with a trailing @. When all the values from the line have

©2002 CRC Press LLC

been read, and output as observations, the days variable is assigned a missing value and the do until loop finishes. The following input statement then releases the data line so that the next line of data from the input file can be read.

For unbalanced designs, the glm procedure should be used rather than proc anova. We begin by fitting main-effects-only models for different orders of main effects.

proc glm data=ozkids;

class origin sex grade type;

model days=origin sex grade type /ss1 ss3;

proc glm data=ozkids;

class origin sex grade type;

model days=grade sex type origin /ss1;

proc glm data=ozkids;

class origin sex grade type;

model days=type sex origin grade /ss1;

proc glm data=ozkids;

class origin sex grade type;

model days=sex origin type grade /ss1; run;

The class statement specifies the classification variables, or factors. These can be numeric or character variables. The model statement specifies the dependent variable on the left-hand side of the equation and the effects (i.e., factors and their interactions) on the right-hand side of the equation. Main effects are specified by including the variable name.

The options in the model statement in the first glm step specify that both Type I and Type III sums of squares are to be output. The subsequent proc steps repeat the analysis, varying the order of the effects; but because Type III sums of squares are invariant to the order, only Type I sums of squares are requested. The output is shown in Display 6.2. Note that when a main effect is ordered last, the corresponding Type I sum of squares is the same as the Type III sum of squares for the factor. In fact, when dealing with a main-effects only model, the Type III sums of squares can legitimately be used to identify the most important effects. Here, it appears that origin and grade have the most impact on the number of days a child is absent from school.

©2002 CRC Press LLC